niriswitcher: add module (#7246)

modules/lib/maintainers.nix

@@ -829,6 +829,12 @@
     githubId = 68489118;
     name = "tomodachi94";
   };
+  vortriz = {
+    name = "Rishi Vora";
+    email = "vorarishi22+nix@gmail.com";
+    github = "Vortriz";
+    githubId = 97402159;
+  };
   wcarlsen = {
     name = "Willi Carlsen";
     email = "carlsenwilli+nix@gmail.com";

modules/misc/news/2025/06/2025-06-09_20-42-11.nix

@@ -0,0 +1,11 @@
+{ pkgs, ... }:
+{
+  time = "2025-06-09T15:12:11+00:00";
+  condition = pkgs.stdenv.hostPlatform.isLinux;
+  message = ''
+    A new module is available: 'programs.niriswitcher'.
+
+    niriswitcher is an application switcher for niri, with support for
+    workspaces and automatic light and dark mode.
+  '';
+}

modules/modules.nix

@@ -212,6 +212,7 @@ let
       ./programs/newsboat.nix
       ./programs/nh.nix
       ./programs/nheko.nix
+      ./programs/niriswitcher.nix
       ./programs/nix-index.nix
       ./programs/nix-init.nix
       ./programs/nix-your-shell.nix

modules/programs/niriswitcher.nix

@@ -0,0 +1,91 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.programs.niriswitcher;
+
+  settingsFormat = pkgs.formats.toml { };
+in
+{
+  meta.maintainers = [ lib.hm.maintainers.vortriz ];
+
+  options.programs.niriswitcher = {
+    enable = lib.mkEnableOption "niriswitcher, an application switcher for niri";
+
+    package = lib.mkPackageOption pkgs "niriswitcher" { nullable = true; };
+
+    settings = lib.mkOption {
+      type = lib.types.nullOr settingsFormat.type;
+      default = null;
+      example = lib.literalExpression ''
+        {
+          keys = {
+            modifier = "Super";
+            switch = {
+              next = "Tab";
+              prev = "Shift+Tab";
+            };
+          };
+          center_on_focus = true;
+          appearance = {
+            system_theme = "dark";
+            icon_size = 64;
+          };
+        }
+      '';
+      description = ''
+        niriswitcher configuration.
+        For available settings see <https://github.com/isaksamsten/niriswitcher/?tab=readme-ov-file#options>.
+      '';
+    };
+
+    style = lib.mkOption {
+      type = with lib.types; nullOr (either path lines);
+      default = null;
+      example = ''
+        .application-name {
+          opacity: 1;
+          color: rgba(255, 255, 255, 0.6);
+        }
+        .application.selected .application-name {
+          color: rgba(255, 255, 255, 1);
+        }
+      '';
+      description = ''
+        CSS style of the switcher.
+        <https://github.com/isaksamsten/niriswitcher/?tab=readme-ov-file#themes>
+        for the documentation.
+
+        If the value is set to a path literal, then the path will be used as the CSS file.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    assertions = [
+      {
+        assertion = pkgs.stdenv.hostPlatform.isLinux;
+        message = "niriswitcher is only available on Linux.";
+      }
+    ];
+
+    home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
+
+    xdg.configFile = {
+      "niriswitcher/config.toml" = lib.mkIf (cfg.settings != null) {
+        source = settingsFormat.generate "config.toml" cfg.settings;
+      };
+
+      "niriswitcher/style.css" = lib.mkIf (cfg.style != null) {
+        source =
+          if builtins.isPath cfg.style || lib.isStorePath cfg.style then
+            cfg.style
+          else
+            pkgs.writeText "niriswitcher/style.css" cfg.style;
+      };
+    };
+  };
+}

tests/default.nix

@@ -405,6 +405,7 @@ import nmtSrc {
       ./modules/programs/mpvpaper
       ./modules/programs/ncmpcpp-linux
       ./modules/programs/nh
+      ./modules/programs/niriswitcher
       ./modules/programs/onagre
       ./modules/programs/onedrive
       ./modules/programs/pqiv

tests/modules/programs/niriswitcher/default.nix

@@ -0,0 +1 @@
+{ niriswitcher-program = ./niriswitcher.nix; }

tests/modules/programs/niriswitcher/expected.toml

@@ -0,0 +1,11 @@
+center_on_focus = true
+[appearance]
+icon_size = 64
+system_theme = "dark"
+
+[keys]
+modifier = "Super"
+
+[keys.switch]
+next = "Tab"
+prev = "Shift+Tab"

tests/modules/programs/niriswitcher/niriswitcher.nix

@@ -0,0 +1,30 @@
+{
+  programs.niriswitcher = {
+    enable = true;
+
+    settings = {
+      center_on_focus = true;
+      keys = {
+        modifier = "Super";
+        switch = {
+          next = "Tab";
+          prev = "Shift+Tab";
+        };
+      };
+      appearance = {
+        system_theme = "dark";
+        icon_size = 64;
+      };
+    };
+
+    style = ./style.css;
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/niriswitcher/config.toml
+    assertFileContent home-files/.config/niriswitcher/config.toml ${./expected.toml}
+
+    assertFileExists home-files/.config/niriswitcher/style.css
+    assertFileContent home-files/.config/niriswitcher/style.css ${./style.css}
+  '';
+}

tests/modules/programs/niriswitcher/style.css

@@ -0,0 +1,7 @@
+.application-name {
+  opacity: 1;
+  color: rgba(255, 255, 255, 0.6);
+}
+.application.selected .application-name {
+  color: rgba(255, 255, 255, 1);
+}