mirror of
https://github.com/CHN-beta/nixpkgs.git
synced 2026-01-11 18:32:23 +08:00
a19cd4ffb1
This reverts commit65a333600d. This wasn't tested for correctness with something like fodwatch [0], and should not have been (self-)merged so quickly, especially without further review. It also resulted in the breakage of at least one package [1] (and that's the one we know of and was caught). A few packages that were updated in between this commit and this revert were not reverted back to using `rev`, but other than that, this is a 1:1 revert. [0]: https://codeberg.org/raphaelr/fodwatch [1]: https://github.com/NixOS/nixpkgs/pull/396904 /758551e458
76 lines
1.4 KiB
Nix
76 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
|
|
legacy ? false,
|
|
libinput,
|
|
|
|
pkg-config,
|
|
makeWrapper,
|
|
|
|
openal,
|
|
alure,
|
|
libXtst,
|
|
libX11,
|
|
}:
|
|
|
|
let
|
|
inherit (lib) optionals;
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "bucklespring";
|
|
version = "1.5.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "zevv";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "0prhqibivxzmz90k79zpwx3c97h8wa61rk5ihi9a5651mnc46mna";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
makeWrapper
|
|
];
|
|
|
|
buildInputs =
|
|
[
|
|
openal
|
|
alure
|
|
]
|
|
++ optionals (legacy) [
|
|
libXtst
|
|
libX11
|
|
]
|
|
++ optionals (!legacy) [ libinput ];
|
|
|
|
makeFlags = optionals (!legacy) [ "libinput=1" ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/share/wav
|
|
cp -r $src/wav $out/share/.
|
|
install -D ./buckle.desktop $out/share/applications/buckle.desktop
|
|
install -D ./buckle $out/bin/buckle
|
|
wrapProgram $out/bin/buckle --add-flags "-p $out/share/wav"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Nostalgia bucklespring keyboard sound";
|
|
mainProgram = "buckle";
|
|
longDescription = ''
|
|
When built with libinput (wayland or bare console),
|
|
users need to be in the input group to use this:
|
|
<code>users.users.alice.extraGroups = [ "input" ];</code>
|
|
'';
|
|
homepage = "https://github.com/zevv/bucklespring";
|
|
license = licenses.gpl2Only;
|
|
platforms = platforms.unix;
|
|
maintainers = [ maintainers.evils ];
|
|
};
|
|
}
|