mirror of
https://github.com/CHN-beta/nixpkgs.git
synced 2026-01-13 19:43:02 +08:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
66 lines
1.6 KiB
Nix
66 lines
1.6 KiB
Nix
{
|
||
stdenv,
|
||
lib,
|
||
fetchFromRepoOrCz,
|
||
buildPythonPackage,
|
||
flit-core,
|
||
pillow,
|
||
python,
|
||
pythonOlder,
|
||
}:
|
||
|
||
# Note: this package is used to build LLVM’s documentation, which is part of the Darwin stdenv.
|
||
# It cannot use `fetchgit` because that would pull curl into the bootstrap, which is disallowed.
|
||
|
||
let
|
||
self = buildPythonPackage rec {
|
||
pname = "docutils";
|
||
version = "0.21.2";
|
||
pyproject = true;
|
||
|
||
disabled = pythonOlder "3.7";
|
||
|
||
src = fetchFromRepoOrCz {
|
||
repo = "docutils";
|
||
rev = "docutils-${version}";
|
||
hash = "sha256-Q+9yW+BYUEvPYV504368JsAoKKoaTZTeKh4tVeiNv5Y=";
|
||
};
|
||
|
||
build-system = [ flit-core ];
|
||
|
||
# infinite recursion via sphinx and pillow
|
||
doCheck = false;
|
||
passthru.tests.pytest = self.overridePythonAttrs { doCheck = true; };
|
||
|
||
nativeCheckInputs = [ pillow ];
|
||
|
||
# Only Darwin needs LANG, but we could set it in general.
|
||
# It's done here conditionally to prevent mass-rebuilds.
|
||
checkPhase =
|
||
lib.optionalString stdenv.hostPlatform.isDarwin ''LANG="en_US.UTF-8" LC_ALL="en_US.UTF-8" ''
|
||
+ ''
|
||
${python.interpreter} test/alltests.py
|
||
'';
|
||
|
||
# Create symlinks lacking a ".py" suffix, many programs depend on these names
|
||
postFixup = ''
|
||
for f in $out/bin/*.py; do
|
||
ln -s $(basename $f) $out/bin/$(basename $f .py)
|
||
done
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "Python Documentation Utilities";
|
||
homepage = "http://docutils.sourceforge.net/";
|
||
license = with licenses; [
|
||
publicDomain
|
||
bsd2
|
||
psfl
|
||
gpl3Plus
|
||
];
|
||
maintainers = with maintainers; [ AndersonTorres ];
|
||
};
|
||
};
|
||
in
|
||
self
|