mirror of
https://github.com/CHN-beta/nixpkgs.git
synced 2026-01-13 19:43:02 +08:00
567e8dfd8e
This commit was created by a combination of scripts and tools: - an ast-grep script to prefix things in meta with `lib.`, - a modified nixf-diagnose / nixf combination to remove unused `with lib;`, and - regular nixfmt. Co-authored-by: Wolfgang Walther <walther@technowledgy.de>
82 lines
1.8 KiB
Nix
82 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
fetchFromGitHub,
|
|
buildPythonPackage,
|
|
pytestCheckHook,
|
|
pycparser,
|
|
psutil,
|
|
dotnet-sdk_6,
|
|
buildDotnetModule,
|
|
clr-loader,
|
|
setuptools,
|
|
}:
|
|
|
|
let
|
|
pname = "pythonnet";
|
|
version = "3.0.5";
|
|
src = fetchFromGitHub {
|
|
owner = "pythonnet";
|
|
repo = "pythonnet";
|
|
tag = "v${version}";
|
|
hash = "sha256-3LBrV/cQrXFKMFE1rCalDsPZ3rOY7RczqXoryMoVi14=";
|
|
};
|
|
|
|
# This buildDotnetModule is used only to get nuget sources, the actual
|
|
# build is done in `buildPythonPackage` below.
|
|
dotnet-build = buildDotnetModule {
|
|
inherit pname version src;
|
|
projectFile = "src/runtime/Python.Runtime.csproj";
|
|
testProjectFile = "src/testing/Python.Test.csproj";
|
|
nugetDeps = ./deps.json;
|
|
dotnet-sdk = dotnet-sdk_6;
|
|
};
|
|
in
|
|
buildPythonPackage {
|
|
inherit pname version src;
|
|
|
|
format = "pyproject";
|
|
|
|
postPatch = ''
|
|
substituteInPlace pyproject.toml \
|
|
--replace 'dynamic = ["version"]' 'version = "${version}"'
|
|
'';
|
|
|
|
buildInputs = dotnet-build.nugetDeps;
|
|
|
|
nativeBuildInputs = [
|
|
setuptools
|
|
dotnet-sdk_6
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
pycparser
|
|
clr-loader
|
|
];
|
|
|
|
pytestFlags = [
|
|
# Run tests using .NET Core, Mono is unsupported for now due to find_library problem in clr-loader
|
|
"--runtime=coreclr"
|
|
];
|
|
|
|
nativeCheckInputs = [
|
|
pytestCheckHook
|
|
psutil # needed for memory leak tests
|
|
];
|
|
|
|
# Rerun this when updating to refresh Nuget dependencies
|
|
passthru.fetch-deps = dotnet-build.fetch-deps;
|
|
|
|
meta = {
|
|
description = ".NET integration for Python";
|
|
homepage = "https://pythonnet.github.io";
|
|
changelog = "https://github.com/pythonnet/pythonnet/releases/tag/${src.tag}";
|
|
license = lib.licenses.mit;
|
|
# <https://github.com/pythonnet/pythonnet/issues/898>
|
|
badPlatforms = [ "aarch64-linux" ];
|
|
maintainers = with lib.maintainers; [
|
|
jraygauthier
|
|
mdarocha
|
|
];
|
|
};
|
|
}
|