From d30f406254bca447c4b9273c7d69bcc4ed5c6f10 Mon Sep 17 00:00:00 2001
From: Moraxyc <i@qaq.li>
Date: Fri, 19 Dec 2025 19:28:20 +0800
Subject: [PATCH 1/2] sub-store: init at 2.20.61

---
 pkgs/by-name/su/sub-store/package.nix | 72 +++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 pkgs/by-name/su/sub-store/package.nix

diff --git a/pkgs/by-name/su/sub-store/package.nix b/pkgs/by-name/su/sub-store/package.nix
new file mode 100644
index 000000000000..cd1c85e268f4
--- /dev/null
+++ b/pkgs/by-name/su/sub-store/package.nix
@@ -0,0 +1,72 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+
+  pnpm_10,
+  pnpm ? pnpm_10,
+  fetchPnpmDeps,
+  pnpmConfigHook,
+  makeBinaryWrapper,
+  nix-update-script,
+
+  nodejs,
+}:
+
+buildNpmPackage (finalAttrs: {
+  pname = "sub-store";
+  version = "2.20.61";
+
+  src = fetchFromGitHub {
+    owner = "sub-store-org";
+    repo = "Sub-Store";
+    tag = finalAttrs.version;
+    hash = "sha256-6NHPVCIlModWXzKOJnPwA41cHrNWy6yXUEwoKpbwpmw=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/backend";
+
+  nativeBuildInputs = [
+    makeBinaryWrapper
+    pnpm
+  ];
+
+  npmDeps = null;
+  pnpmDeps = fetchPnpmDeps {
+    inherit (finalAttrs)
+      pname
+      version
+      src
+      sourceRoot
+      ;
+    inherit pnpm;
+    fetcherVersion = 3;
+    hash = "sha256-VsK6qvBeOF2smXRFmMk4gWxQgAD1GG/ExvZdIERdz9g=";
+  };
+
+  npmConfigHook = pnpmConfigHook;
+  npmBuildScript = "bundle:esbuild";
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share
+    cp -r dist $out/share/sub-store
+    makeWrapper ${lib.getExe nodejs} $out/bin/sub-store \
+      --add-flags "$out/share/sub-store/sub-store.bundle.js"
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Advanced Subscription Manager for QX, Loon, Surge, Stash, Egern and Shadowrocket";
+    homepage = "https://github.com/sub-store-org/Sub-Store";
+    changelog = "https://github.com/sub-store-org/Sub-Store/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [ moraxyc ];
+    mainProgram = "sub-store";
+    platforms = nodejs.meta.platforms;
+  };
+})

From 89c6819a44f2804a08cd24075f9a5924448a3519 Mon Sep 17 00:00:00 2001
From: Moraxyc <i@qaq.li>
Date: Fri, 19 Dec 2025 19:40:22 +0800
Subject: [PATCH 2/2] sub-store-frontend: init at 2.15.85

---
 .../by-name/su/sub-store-frontend/package.nix | 58 +++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 pkgs/by-name/su/sub-store-frontend/package.nix

diff --git a/pkgs/by-name/su/sub-store-frontend/package.nix b/pkgs/by-name/su/sub-store-frontend/package.nix
new file mode 100644
index 000000000000..0bbdf7428215
--- /dev/null
+++ b/pkgs/by-name/su/sub-store-frontend/package.nix
@@ -0,0 +1,58 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+
+  pnpm_10,
+  pnpm ? pnpm_10,
+  fetchPnpmDeps,
+  pnpmConfigHook,
+  nix-update-script,
+  nodejs,
+}:
+
+buildNpmPackage (finalAttrs: {
+  pname = "sub-store-frontend";
+  version = "2.15.85";
+
+  src = fetchFromGitHub {
+    owner = "sub-store-org";
+    repo = "Sub-Store-Front-End";
+    tag = finalAttrs.version;
+    hash = "sha256-K7tAqbM7cQpmZmRQFwJhpiesUoPzvXEKu5q0pYsj+ZA=";
+  };
+
+  nativeBuildInputs = [
+    nodejs
+    pnpm
+  ];
+
+  npmDeps = null;
+  pnpmDeps = fetchPnpmDeps {
+    inherit (finalAttrs) pname version src;
+    inherit pnpm;
+    fetcherVersion = 3;
+    hash = "sha256-HEeNYLKvzO/RQWYnm5gqRjTrXiiCxKUxf3bcRvz+O4k=";
+  };
+
+  npmConfigHook = pnpmConfigHook;
+
+  installPhase = ''
+    runHook preInstall
+
+    cp -r dist $out
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Sub-Store Progressive Web App";
+    homepage = "https://github.com/sub-store-org/Sub-Store-Front-End";
+    changelog = "https://github.com/sub-store-org/Sub-Store-Front-End/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ moraxyc ];
+    platforms = nodejs.meta.platforms;
+  };
+})