From 98722542d9a624e08ed7af62b8180fcf5c56ffde Mon Sep 17 00:00:00 2001
From: Mynacol <Mynacol@users.noreply.github.com>
Date: Mon, 9 Sep 2024 15:44:29 +0200
Subject: [PATCH] git-identity: init at 1.1.1

Co-authored-by: Sandro <sandro.jaeckel@gmail.com>
---
 pkgs/by-name/gi/git-identity/package.nix | 52 ++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 pkgs/by-name/gi/git-identity/package.nix

diff --git a/pkgs/by-name/gi/git-identity/package.nix b/pkgs/by-name/gi/git-identity/package.nix
new file mode 100644
index 000000000000..51addeebc16c
--- /dev/null
+++ b/pkgs/by-name/gi/git-identity/package.nix
@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  installShellFiles,
+  ronn,
+  nix-update-script,
+}:
+stdenvNoCC.mkDerivation rec {
+  pname = "git-identity";
+  version = "1.1.1";
+
+  src = fetchFromGitHub {
+    owner = "madx";
+    repo = "git-identity";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-u4lIW0bntaKrVUwodXZ8ZwWxSZtLuhVSUAbIj8jjcLw=";
+  };
+
+  nativeBuildInputs = [
+    installShellFiles
+    ronn
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+    ronn --roff git-identity.1.ronn
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp git-identity $out/bin/git-identity
+    installManPage git-identity.1
+    installShellCompletion --cmd git-identity \
+      --bash git-identity.bash-completion \
+      --zsh git-identity.zsh-completion
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Manage your identity in Git";
+    mainProgram = "git-identity";
+    homepage = "https://github.com/madx/git-identity";
+    license = lib.licenses.wtfpl;
+    maintainers = with lib.maintainers; [ mynacol ];
+    platforms = lib.platforms.all;
+  };
+}