{ stdenv, lib, fetchurl, zlib }:

with lib;

stdenv.mkDerivation rec {
  name = "sauce-connect-${version}";
  version = "4.3.6";

  src = fetchurl (
    if stdenv.system == "x86_64-linux" then {
      url = "https://saucelabs.com/downloads/sc-${version}-linux.tar.gz";
      sha1 = "0d7d2dc12766ac137e62a3e4dad3025b590f9782";
    } else {
      url = "https://saucelabs.com/downloads/sc-${version}-linux32.tar.gz";
      sha1 = "ee2c3002eae3b29df801a2ac1db77bb5f1c97bcc";
    }
  );

  patchPhase = ''
    patchelf \
      --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
      --set-rpath "$out/lib:${makeLibraryPath [zlib]}" \
      bin/sc
  '';

  installPhase = ''
    mkdir -p $out
    cp -r * $out
  '';

  dontStrip = true;

  meta = {
    description = "A secure tunneling app for executing tests securely when testing behind firewalls";
    license = licenses.unfree;
    homepage = https://docs.saucelabs.com/reference/sauce-connect/;
    maintainers = with maintainers; [offline];
    platforms = with platforms; platforms.linux;
  };
}
