mirror of
https://github.com/nix-community/home-manager.git
synced 2026-01-11 09:29:41 +08:00
f9ce7c5234
Migrates from the deprecated toCommandLineShell to toCommandLineShellGNU. This changes the output format to use GNU-style concatenated options (--line-height=28) and adds shell escaping for values with special characters (e.g., '#1e1e2e' becomes '--ab=#1e1e2e'). The format was verified to work correctly with bemenu. Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
61 lines
1.3 KiB
Nix
61 lines
1.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.programs.bemenu;
|
|
in
|
|
{
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.bemenu = {
|
|
enable = lib.mkEnableOption "bemenu";
|
|
|
|
package = lib.mkPackageOption pkgs "bemenu" { nullable = true; };
|
|
|
|
settings = lib.mkOption {
|
|
type =
|
|
with lib.types;
|
|
attrsOf (oneOf [
|
|
str
|
|
number
|
|
bool
|
|
]);
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
line-height = 28;
|
|
prompt = "open";
|
|
ignorecase = true;
|
|
fb = "#1e1e2e";
|
|
ff = "#cdd6f4";
|
|
nb = "#1e1e2e";
|
|
nf = "#cdd6f4";
|
|
tb = "#1e1e2e";
|
|
hb = "#1e1e2e";
|
|
tf = "#f38ba8";
|
|
hf = "#f9e2af";
|
|
af = "#cdd6f4";
|
|
ab = "#1e1e2e";
|
|
width-factor = 0.3;
|
|
}
|
|
'';
|
|
description = "Configuration options for bemenu. See {manpage}`bemenu(1)`.";
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "programs.bemenu" pkgs lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
|
|
|
|
home.sessionVariables = lib.mkIf (cfg.settings != { }) {
|
|
BEMENU_OPTS = lib.cli.toCommandLineShellGNU { } cfg.settings;
|
|
};
|
|
};
|
|
}
|