bscpkgs/garlic/exp/fwi/ss.nix

# Strong scaling test for FWI variants based on tasks. This
# experiment explores a range of block sizes deemed as efficient
# according to the granularity experiment.

{
  stdenv
, stdexp
, bsc
, targetMachine
, stages
, garlicTools
, callPackage
, enableExtended ? false
}:

with stdenv.lib;
with garlicTools;

let

  common = callPackage ./common.nix {};

  inherit (targetMachine) fs;

  # Initial variable configuration
  varConf = {
    gitBranch = [
      "garlic/tampi+isend+oss+task"
    ] ++ optionals (enableExtended) [
      "garlic/tampi+send+oss+task"
      "garlic/mpi+send+omp+task"
      "garlic/mpi+send+oss+task"
      "garlic/mpi+send+omp+fork"
    ];

    blocksize = if (enableExtended)
      then range2 1 16
      else [ 2 ];

    n = [ {nx=100; nz=100; ny=8000;} ];

    nodes = range2 1 16;
  };

  machineConfig = targetMachine.config;

  # Generate the complete configuration for each unit
  genConf = c: machineConfig // rec {
    expName = "fwi-ss";
    unitName = "${expName}"
    + "-nodes${toString nodes}"
    + "-bs${toString blocksize}"
    + "-${toString gitBranch}";

    inherit (machineConfig) hw;
    inherit (c) gitBranch blocksize;
    inherit (c.n) nx ny nz;

    fwiInput = bsc.apps.fwi.input.override {
      inherit (c.n) nx ny nz;
    };

    # Other FWI parameters
    ioFreq = -1;

    # Repeat the execution of each unit several times
    loops = 10;

    # Resources
    cpusPerTask = hw.cpusPerSocket;
    ntasksPerNode = hw.socketsPerNode;
    nodes = c.nodes;
    qos = "debug";
    time = "02:00:00";
    jobName = unitName;

    enableCTF = false;

    # Enable permissions to write in the local storage
    extraMounts = [ fs.local.temp ];
    tempDir = fs.local.temp;
  };

  # Compute the array of configurations
  allConfigs = stdexp.buildConfigs {
    inherit varConf genConf;
  };

  # The unique function ensures that we only run one config for the fork
  # join branch, even if we have multiple blocksizes.
  configs = unique (map fixBlocksize allConfigs);

  inherit (common) fixBlocksize pipeline;

in
 
  stdexp.genExperiment { inherit configs pipeline; }